wire-server/shell.nix at develop · mansres/wire-server · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
{ pkgs ? import ./nix }:
let
  staticBinaryInTarball = { pname, version, linuxAmd64Url, linuxAmd64Sha256, darwinAmd64Url, darwinAmd64Sha256, binPath ? pname }:
    pkgs.stdenv.mkDerivation {
      inherit pname version;

      src =
        if pkgs.stdenv.isDarwin
        then pkgs.fetchurl {
          url = darwinAmd64Url;
          sha256 = darwinAmd64Sha256;
        }
        else pkgs.fetchurl {
          url = linuxAmd64Url;
          sha256 = linuxAmd64Sha256;
        };

      installPhase = ''
        mkdir -p $out/bin
        cp ${binPath} $out/bin
      '';
    };
  pinned = {
    stack = staticBinaryInTarball {
      pname = "stack";
      version = "2.3.1";

      darwinAmd64Url = "https://github.com/commercialhaskell/stack/releases/download/v2.3.1/stack-2.3.1-osx-x86_64.tar.gz";
      darwinAmd64Sha256 = "089nrb8mxf76a0r0hdccaxfvx1ly24b5zc0cy05gs4adybjygvkk";

      linuxAmd64Url = "https://github.com/commercialhaskell/stack/releases/download/v2.3.1/stack-2.3.1-linux-x86_64-static.tar.gz";
      linuxAmd64Sha256 = "0iqfqcd88rvlwgm2h8avs0rsi9f3pdxilvcacgrxskb1n8q8ibjb";
    };

    helm = staticBinaryInTarball {
      pname = "helm";
      version = "3.1.1";

      darwinAmd64Url = "https://get.helm.sh/helm-v3.1.1-darwin-amd64.tar.gz";
      darwinAmd64Sha256 = "2ce00e6c44ba18fbcbec21c493476e919128710d480789bb35bd228ae695cd66";

      linuxAmd64Url = "https://get.helm.sh/helm-v3.1.1-linux-amd64.tar.gz";
      linuxAmd64Sha256 = "cdd7ad304e2615c583dde0ffb0cb38fc1336cd7ce8ff3b5f237434dcadb28c98";
    };

    kubectl = staticBinaryInTarball {
      pname = "kubectl";
      version = "1.19.8";

      darwinAmd64Url = "https://dl.k8s.io/v1.19.8/kubernetes-client-darwin-amd64.tar.gz";
      darwinAmd64Sha256 = "23b847bb8b545c748e9078e7660c654eef74d15ccab8696d294f3d6c619c788e";

      linuxAmd64Url = "https://dl.k8s.io/v1.19.8/kubernetes-client-linux-amd64.tar.gz";
      linuxAmd64Sha256 = "8388ff8b5c676bdbb8fe07ef7077de937b0bf60154f302df5f248f38f95122aa";

      binPath = "client/bin/kubectl";
    };
  };
in pkgs.mkShell {
  name = "shell";
  LOCALE_ARCHIVE = "${pkgs.glibcLocales}/lib/locale/locale-archive"; # works around https://github.com/tweag/ormolu/issues/38
  buildInputs = [
    pkgs.docker-compose
    pkgs.gnumake
    pkgs.haskell-language-server
    pkgs.telepresence
    pkgs.jq
    pkgs.grpcurl
    pkgs.wget
    pkgs.cfssl
    pkgs.yq

    # To actually run buildah on nixos, I had to follow this: https://gist.github.com/alexhrescale/474d55635154e6b2cd6362c3bb403faf
    pkgs.buildah
    pkgs.kind

    pinned.stack
    pinned.helm
    pinned.kubectl
  ];
}