migaman/flake.nix at main · ozkutuk/migaman · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
{
  description = "migaman";

  inputs = {
    flake-parts.url = "github:hercules-ci/flake-parts";
    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
  };

  outputs = inputs:
    inputs.flake-parts.lib.mkFlake {inherit inputs;} ({
      flake-parts-lib,
      moduleWithSystem,
      ...
    }: {
      systems = [
        "aarch64-darwin"
        "aarch64-linux"
        "x86_64-darwin"
        "x86_64-linux"
      ];
      perSystem = {
        pkgs,
        system,
        config,
        ...
      }: let
        pkgs = inputs.nixpkgs.legacyPackages.${system};
        pkgsStatic = inputs.nixpkgs.legacyPackages.${system}.pkgsMusl;
        myOverlay = pkgs.haskell.lib.compose.packageSourceOverrides {
          migaman = ./.;
          migadu = ./migadu;
        };
        hsPkgs = pkgs.haskellPackages.extend myOverlay;
        fixGhc = pkg: pkg.override {
          enableRelocatedStaticLibs = true;
          enableShared = false;
          enableDwarf = false;
        };
        hsPkgsStatic = (pkgsStatic.haskellPackages.override (old: {
          ghc = fixGhc old.ghc;
          buildHaskellPackages = old.buildHaskellPackages.override (oldBHP: {
            ghc = fixGhc oldBHP.ghc;
          });
        })).extend myOverlay;

      in {
        devShells.default = hsPkgs.shellFor {
          packages = p: [p.migaman p.migadu];
          nativeBuildInputs = [
            hsPkgs.cabal-install
            hsPkgs.haskell-language-server
            hsPkgs.fourmolu
            hsPkgs.cabal-fmt

            pkgs.just
            pkgs.sqlite
            pkgs.sqlitebrowser
          ];
        };

        packages.migaman = pkgs.haskell.lib.justStaticExecutables hsPkgs.migaman;
        packages.migaman-static = (pkgs.haskell.lib.overrideCabal hsPkgsStatic.migaman (old: {
          postInstall = (old.postInstall or "") + ''
            for b in $out/bin/*
            do
              if ldd "$b"
              then
                echo "ldd succeeded on $b, which may mean that it is not statically linked"
                exit 1
              fi
            done
          '';
          configureFlags = (old.configureFlags or [ ]) ++ [
            "--ghc-option=-optl=-static"
            "--extra-lib-dirs=${pkgsStatic.gmp6.override { withStatic = true; }}/lib"
            "--extra-lib-dirs=${pkgsStatic.libffi.overrideAttrs (old: { dontDisableStatic = true; })}/lib"
            "--extra-lib-dirs=${pkgsStatic.zlib.static}/lib"
          ];
          enableSharedExecutables = false;
          enableSharedLibraries = false;
        })).overrideAttrs (old: {
          postPhases = (old.postPhases or [ ]) ++ ["compressionPhase"];
          nativeBuildInputs = old.nativeBuildInputs ++ [pkgs.upx];
          compressionPhase = ''
            echo "compressing the executable"
            upx --best $out/bin/migaman
          '';
        });

        packages.default = config.packages.migaman;

        formatter = pkgs.alejandra;
      };
      flake = {config, ...}: {
        homeManagerModules = {
          migaman = moduleWithSystem (
            perSystem @ {config}: flake-parts-lib.importApply ./nix/migaman.nix perSystem
          );
          default = config.homeManagerModules.migaman;
        };
      };
    });
}