BazelCon 2025 の登録と CFP が開始されました。

このページは Cloud Translation API によって翻訳されました。

Bazel で Android Native Development Kit を使用する

問題を報告ソースを表示 Nightly · 8.3 · 8.2 · 8.1 · 8.0 · 7.6

Bazel を初めて使用する場合は、まず Bazel を使用した Android のビルドのチュートリアルをご覧ください。

概要

Bazel は、Android Native Development Kit（NDK）ツールチェーンを使用する構成など、さまざまなビルド構成で実行できます。つまり、通常の cc_library ルールと cc_binary ルールは、Bazel 内で Android 向けに直接コンパイルできます。Bazel は、android_ndk_repository リポジトリルールとその関連する bzlmod 拡張機能を使用して、これを実現します。

一般的な Android コンパイルには、rules_android を使用します。このチュートリアルでは、C++ ライブラリの依存関係を Android アプリに統合する方法について説明します。また、NDK ツールチェーンの検出と登録に rules_android_ndk を使用します。

前提条件

Android SDK と NDK がインストールされていることを確認してください。

NDK と SDK の設定

外部リポジトリの設定は、WORKSPACE と bzlmod（MODULE.bazel）のどちらを使用するかによって異なります。Bzlmod は Bazel 7 以降の推奨ソリューションです。MODULE.bazel と WORKSPACE の設定スタンザは互いに独立しています。1 つの依存関係管理ソリューションを使用している場合は、もう一方のボイラープレートを追加する必要はありません。

Bzlmod の MODULE.bazel の設定

MODULE.bazel に次のスニペットを追加します。

# NDK
bazel_dep(name = "rules_android_ndk", version = "0.1.3")
android_ndk_repository_extension = use_extension("@rules_android_ndk//:extension.bzl", "android_ndk_repository_extension")
use_repo(android_ndk_repository_extension, "androidndk")
register_toolchains("@androidndk//:all")

# SDK
bazel_dep(name = "rules_android", version = "0.6.6")
register_toolchains(
    "@rules_android//toolchains/android:android_default_toolchain",
    "@rules_android//toolchains/android_sdk:android_sdk_tools",
)
android_sdk_repository_extension = use_extension("@rules_android//rules/android_sdk_repository:rule.bzl", "android_sdk_repository_extension")
use_repo(android_sdk_repository_extension, "androidsdk")
register_toolchains("@androidsdk//:sdk-toolchain", "@androidsdk//:all")

以前の WORKSPACE の設定

WORKSPACE に次のスニペットを追加します。

load("@rules_android//rules:rules.bzl", "android_sdk_repository")
android_sdk_repository(
    name = "androidsdk", # Required. Name *must* be "androidsdk".
    path = "/path/to/sdk", # Optional. Can be omitted if `ANDROID_HOME` environment variable is set.
)

load("@rules_android_ndk//:rules.bzl", "android_ndk_repository")
android_ndk_repository(
    name = "androidndk", # Required. Name *must* be "androidndk".
    path = "/path/to/ndk", # Optional. Can be omitted if `ANDROID_NDK_HOME` environment variable is set.
)

WORKSPACE の互換性に関する注意事項:

rules_android ルールと rules_android_ndk ルールの両方で、上記の WORKSPACE スニペットには示されていない追加のボイラープレートが必要です。最新の完全なインスタンス化スタンザについては、rules_android_ndk の基本的なサンプルアプリの WORKSPACE ファイルをご覧ください。

android_ndk_repository ルールの詳細については、ドキュメント文字列をご覧ください。

クイックスタート

Android 用の C++ をビルドするには、android_binary ルールまたは android_library ルールに cc_library 依存関係を追加するだけです。

たとえば、Android アプリの次の BUILD ファイルがあるとします。

# In <project>/app/src/main/BUILD.bazel
load("@rules_cc//cc:cc_library.bzl", "cc_library")
load("@rules_android//rules:rules.bzl", "android_binary", "android_library")

cc_library(
    name = "jni_lib",
    srcs = ["cpp/native-lib.cpp"],
)

android_library(
    name = "lib",
    srcs = ["java/com/example/android/bazel/MainActivity.java"],
    resource_files = glob(["res/**/*"]),
    custom_package = "com.example.android.bazel",
    manifest = "LibraryManifest.xml",
    deps = [":jni_lib"],
)

android_binary(
    name = "app",
    deps = [":lib"],
    manifest = "AndroidManifest.xml",
)

この BUILD ファイルにより、次のターゲットグラフが生成されます。

検索結果の例

図 1. cc_library 依存関係を含む Android プロジェクトのビルドグラフ。

アプリをビルドするには、次のコマンドを実行します。

bazel build //app/src/main:app --android_platforms=<your platform>

--android_platforms を指定しないと、JNI ヘッダーがないというエラーが発生してビルドが失敗します。

bazel build コマンドは、Java ファイル、Android リソースファイル、cc_library ルールをコンパイルし、すべてを APK にパッケージ化します。

$ zipinfo -1 bazel-bin/app/src/main/app.apk
nativedeps
lib/armeabi-v7a/libapp.so
classes.dex
AndroidManifest.xml
...
res/...
...
META-INF/CERT.SF
META-INF/CERT.RSA
META-INF/MANIFEST.MF

Bazel は、すべての cc_libraries を単一の共有オブジェクト（.so）ファイルにコンパイルし、--android_platforms で指定されたアーキテクチャをターゲットにします。詳しくは、ターゲット ABI の構成のセクションをご覧ください。

設定例

この例は、Bazel のサンプルリポジトリで入手できます。

BUILD.bazel ファイルでは、android_binary、android_library、cc_library のルールで 3 つのターゲットが定義されています。

android_binary 最上位のターゲットは APK をビルドします。

cc_library ターゲットには、JNI 関数の実装を含む 1 つの C++ ソースファイルが含まれています。

#include <jni.h>
#include <string>

extern "C"
JNIEXPORT jstring

JNICALL
Java_com_example_android_bazel_MainActivity_stringFromJNI(
        JNIEnv *env,
        jobject /* this */) {
    std::string hello = "Hello from C++";
    return env->NewStringUTF(hello.c_str());
}

android_library ターゲットは、Java ソース、リソースファイル、cc_library ターゲットへの依存関係を指定します。この例では、MainActivity.java は共有オブジェクトファイル libapp.so を読み込み、JNI 関数のメソッドシグネチャを定義します。

public class MainActivity extends AppCompatActivity {

    static {
        System.loadLibrary("app");
    }

    @Override
    protected void onCreate(Bundle savedInstanceState) {
       // ...
    }

    public native String stringFromJNI();

}

ターゲット ABI の構成

ターゲット ABI を構成するには、次のように --android_platforms フラグを使用します。

bazel build //:app --android_platforms=comma-separated list of platforms

--platforms フラグと同様に、--android_platforms に渡される値は、標準の制約値を使用してデバイスを記述する platform ターゲットのラベルです。

たとえば、64 ビット ARM プロセッサを搭載した Android デバイスの場合、プラットフォームは次のように定義します。

platform(
    name = "android_arm64",
    constraint_values = [
        "@platforms//os:android",
        "@platforms//cpu:arm64",
    ],
)

すべての Android platform で @platforms//os:android OS 制約を使用する必要があります。CPU 制約を移行するには、次のグラフを確認してください。

CPU 値	プラットフォーム
`armeabi-v7a`	`@platforms//cpu:armv7`
`arm64-v8a`	`@platforms//cpu:arm64`
`x86`	`@platforms//cpu:x86_32`
`x86_64`	`@platforms//cpu:x86_64`

もちろん、マルチアーキテクチャ APK の場合は、複数のラベルを渡します（例: --android_platforms=//:arm64,//:x86_64。最上位の BUILD.bazel ファイルで定義されていると仮定します）。

Bazel はデフォルトの Android プラットフォームを選択できないため、--android_platforms で定義して指定する必要があります。

NDK リビジョンと Android API レベルに応じて、次の ABI を使用できます。

NDK リビジョン	ABI
16 以下	armeabi、armeabi-v7a、arm64-v8a、mips、mips64、x86、x86_64
17 以上	armeabi-v7a、arm64-v8a、x86、x86_64

これらの ABI について詳しくは、NDK ドキュメントをご覧ください。

マルチ ABI ファット APK は、APK のサイズが増加するためリリースビルドには推奨されませんが、開発ビルドや QA ビルドには役立ちます。

C++ 標準を選択する

C++ 標準に従ってビルドするには、次のフラグを使用します。

C++ 標準	フラグ
C++98	デフォルト。フラグは不要
C++11	`--cxxopt=-std=c++11`
C++14	`--cxxopt=-std=c++14`
C++17	`--cxxopt=-std=c++17`

次に例を示します。

bazel build //:app --cxxopt=-std=c++11

--cxxopt、--copt、--linkopt を使用したコンパイラフラグとリンカーフラグの受け渡しについては、ユーザーマニュアルをご覧ください。

コンパイラフラグとリンカーフラグは、copts と linkopts を使用して cc_library の属性として指定することもできます。次に例を示します。

cc_library(
    name = "jni_lib",
    srcs = ["cpp/native-lib.cpp"],
    copts = ["-std=c++11"],
    linkopts = ["-ldl"], # link against libdl
)

`android_binary` を使用せずに Android 用の `cc_library` をビルドする

android_binary を使用せずに Android 用のスタンドアロン cc_binary または cc_library をビルドするには、--platforms フラグを使用します。

たとえば、my/platforms/BUILD で Android プラットフォームを定義しているとします。

bazel build //my/cc/jni:target \
      --platforms=//my/platforms:x86_64

このアプローチでは、ビルドツリー全体が影響を受けます。

これらのフラグは、project/.bazelrc の bazelrc 構成（ABI ごとに 1 つ）に配置できます。

common:android_x86 --platforms=//my/platforms:x86

common:android_armeabi-v7a --platforms=//my/platforms:armeabi-v7a

# In general
common:android_<abi> --platforms=//my/platforms:<abi>

たとえば、x86 の cc_library をビルドするには、次のコマンドを実行します。

bazel build //my/cc/jni:target --config=android_x86

一般に、このメソッドは低レベルのターゲット（cc_library など）や、ビルドする内容が正確にわかっている場合に使用します。制御できないターゲットを多数ビルドすることが想定される高レベルのターゲットでは、android_binary からの自動構成の移行に依存します。