C++ 도구 모음 구성

개요

올바른 옵션으로 컴파일러를 호출하려면 Bazel이 포함 디렉터리, 중요한 플래그와 같은 컴파일러 내부 구조에 관한 지식이 필요합니다. 즉, Bazel은 컴파일러의 작동 방식을 이해하기 위해 컴파일러의 단순화된 모델이 필요합니다.

Bazel은 다음을 알아야 합니다.

• 컴파일러가 thinLTO, 모듈, 동적 연결 또는 PIC(위치 독립적 코드)를 지원하는지 여부입니다.
• gcc, ld, ar, objcopy 등 필수 도구의 경로입니다.
• 내장 시스템 포함 디렉터리입니다. Bazel은 소스 파일에 포함된 모든 헤더가 BUILD 파일에 올바르게 선언되었는지 확인하기 위해 이러한 정보가 필요합니다.
• 기본 sysroot입니다.
• 컴파일, 연결, 보관에 사용할 플래그
• 지원되는 컴파일 모드 (opt, dbg, fastbuild)에 사용할 플래그
• 컴파일러에서 특별히 요구하는 변수를 만듭니다.

컴파일러가 여러 아키텍처를 지원하는 경우 Bazel은 이를 별도로 구성해야 합니다.

CcToolchainConfigInfo는 Bazel의 C++ 규칙 동작을 구성하는 데 필요한 세부사항 수준을 제공하는 제공자입니다. 기본적으로 Bazel은 빌드에 대해 CcToolchainConfigInfo를 자동으로 구성하지만 수동으로 구성할 수도 있습니다. 이를 위해서는 CcToolchainConfigInfo를 제공하는 Starlark 규칙이 필요하며 cc_toolchain의 toolchain_config 속성을 규칙에 지정해야 합니다. cc_common.create_cc_toolchain_config_info()를 호출하여 CcToolchainConfigInfo를 만들 수 있습니다. 프로세스에 필요한 모든 구조체의 Starlark 생성자는 @rules_cc//cc:cc_toolchain_config_lib.bzl에서 확인할 수 있습니다.

C++ 타겟이 분석 단계에 들어가면 Bazel은 BUILD 파일을 기반으로 적절한 cc_toolchain 타겟을 선택하고 cc_toolchain.toolchain_config 속성에 지정된 타겟에서 CcToolchainConfigInfo 제공자를 가져옵니다. cc_toolchain 타겟은 CcToolchainProvider를 통해 이 정보를 C++ 타겟에 전달합니다.

예를 들어 cc_binary 또는 cc_library과 같은 규칙으로 인스턴스화된 컴파일 또는 링크 작업에는 다음 정보가 필요합니다.

• 사용할 컴파일러 또는 링커
• 컴파일러/링커의 명령줄 플래그
• --copt/--linkopt 옵션을 통해 전달된 구성 플래그
• 환경 변수
• 작업이 실행되는 샌드박스에 필요한 아티팩트

샌드박스에 필요한 아티팩트를 제외한 위의 모든 정보는 cc_toolchain가 가리키는 Starlark 타겟에 지정됩니다.

샌드박스로 전송할 아티팩트는 cc_toolchain 타겟에 선언됩니다. 예를 들어 cc_toolchain.linker_files 속성을 사용하면 샌드박스로 전송할 링커 바이너리와 도구 모음 라이브러리를 지정할 수 있습니다.

도구 모음 선택

툴체인 선택 로직은 다음과 같이 작동합니다.

1. 사용자가 BUILD 파일에서 cc_toolchain_suite 타겟을 지정하고 --crosstool_top 옵션을 사용하여 Bazel이 타겟을 가리키도록 합니다.

2. cc_toolchain_suite 타겟이 여러 도구 모음을 참조합니다. --cpu 및 --compiler 플래그의 값은 해당 도구 체인 중 어떤 것이 선택되는지 결정합니다. --cpu 플래그 값만 기반으로 하거나 공동 --cpu | --compiler 값을 기반으로 합니다. 선정 절차는 다음과 같습니다.

   • --compiler 옵션을 지정하면 Bazel이 --cpu | --compiler를 사용하여 cc_toolchain_suite.toolchains 속성에서 해당 항목을 선택합니다. Bazel이 해당 항목을 찾지 못하면 오류가 발생합니다.

   • --compiler 옵션을 지정하지 않으면 Bazel은 --cpu만 있는 cc_toolchain_suite.toolchains 속성에서 해당 항목을 선택합니다.

   • 플래그를 지정하지 않으면 Bazel이 호스트 시스템을 검사하고 결과를 기반으로 --cpu 값을 선택합니다. 검사 메커니즘 코드를 참고하세요.

툴체인이 선택되면 Starlark 규칙의 해당 feature 및 action_config 객체가 빌드 구성을 관리합니다 (즉, 나중에 설명하는 항목). 이러한 메시지를 사용하면 Bazel 바이너리를 수정하지 않고 Bazel에서 완전한 C++ 기능을 구현할 수 있습니다. C++ 규칙은 Bazel 소스 코드에 자세히 설명된 여러 고유 작업을 지원합니다.

기능

기능은 명령줄 플래그, 작업, 실행 환경의 제약 조건 또는 종속 항목 변경이 필요한 항목입니다. 기능은 BUILD 파일이 treat_warnings_as_errors과 같은 플래그 구성을 선택하거나 C++ 규칙과 상호작용하고 header_modules 또는 thin_lto과 같은 컴파일에 새 컴파일 작업과 입력을 포함하도록 허용하는 것만큼 간단할 수 있습니다.

CcToolchainConfigInfo에는 기능 목록이 포함되어야 합니다. 각 기능은 하나 이상의 플래그 그룹으로 구성되며 각 그룹은 특정 Bazel 작업에 적용되는 플래그 목록을 정의합니다.

기능은 이름으로 지정되므로 Bazel 출시에서 Starlark 규칙 구성을 완전히 분리할 수 있습니다. 즉, Bazel 출시가 CcToolchainConfigInfo 구성의 동작에 영향을 미치지 않습니다. 단, 이러한 구성에 새 기능을 사용해야 하는 경우는 예외입니다.

기능은 다음 방법 중 하나로 사용 설정됩니다.

• 기능의 enabled 필드가 true로 설정됩니다.
• Bazel 또는 규칙 소유자가 명시적으로 사용 설정합니다.
• 사용자가 --feature Bazel 옵션 또는 features 규칙 속성을 통해 이를 사용 설정합니다.

기능은 상호 종속성이 있을 수 있으며, 명령줄 플래그, BUILD 파일 설정, 기타 변수에 따라 달라질 수 있습니다.

기능 관계

종속 항목은 일반적으로 Bazel로 직접 관리되며, Bazel은 요구사항을 적용하고 빌드에 정의된 기능의 본질에 내재된 충돌을 관리합니다. 툴체인 사양을 사용하면 기능 지원 및 확장을 관리하는 Starlark 규칙 내에서 직접 사용할 수 있는 더 세분화된 제약 조건이 허용됩니다. 이는 다음과 같습니다.

requires = [
   feature_set (features = [
       'feature-name-1',
       'feature-name-2'
   ]),
]

implies = ['feature']

provides = ['feature']

with_features = [
  with_feature_set(
    features = ['feature-1'],
    not_features = ['feature-2'],
  ),
]

작업

작업은 작업이 실행되는 방식을 가정하지 않고도 작업이 실행되는 상황을 수정할 수 있는 유연성을 제공합니다. action_config는 작업이 호출하는 도구 바이너리를 지정하고 feature는 작업이 호출될 때 해당 도구가 작동하는 방식을 결정하는 구성 (플래그)을 지정합니다.

작업이 Bazel 작업 그래프를 수정할 수 있으므로 기능은 영향을 미치는 Bazel 작업을 나타내는 작업을 참조합니다. CcToolchainConfigInfo 제공자에는 c++-compile와 같이 플래그 및 도구가 연결된 작업이 포함됩니다. 플래그는 기능을 연결하여 각 작업에 할당됩니다.

각 작업 이름은 컴파일 또는 연결과 같이 Bazel에서 실행하는 단일 유형의 작업을 나타냅니다. 하지만 액션과 Bazel 액션 유형 간에는 다대일 관계가 있습니다. 여기서 Bazel 액션 유형은 액션 (예: CppCompileAction)을 구현하는 Java 클래스를 나타냅니다. 특히 아래 표의 '어셈블러 액션'과 '컴파일러 액션'은 CppCompileAction이고 링크 액션은 CppLinkAction입니다.

어셈블러 작업

컴파일러 작업

링크 작업

AR 작업

AR 작업은 ar을 통해 객체 파일을 보관 파일 라이브러리 (.a 파일)로 어셈블하고 일부 시맨틱을 이름으로 인코딩합니다.

LTO 작업

action_config 사용

action_config는 작업 중에 호출할 도구 (바이너리)를 지정하고 기능으로 정의된 플래그 집합을 설정하여 Bazel 작업을 설명하는 Starlark 구조체입니다. 이러한 플래그는 작업의 실행에 제약 조건을 적용합니다.

action_config() 생성자에는 다음과 같은 매개변수가 있습니다.

action_config는 앞서 설명한 기능 관계에 따라 다른 기능과 action_config를 요구하고 암시할 수 있습니다. 이 동작은 기능의 동작과 유사합니다.

마지막 두 속성은 기능의 해당 속성과 중복되며 일부 Bazel 작업에 특정 플래그나 환경 변수가 필요하고 불필요한 action_config+feature 쌍을 방지하는 것이 목표이므로 포함됩니다. 일반적으로 여러 action_config에서 단일 기능을 공유하는 것이 좋습니다.

동일한 도구 모음 내에서 동일한 action_name을(를) 가진 action_config을(를) 두 개 이상 정의할 수 없습니다. 이렇게 하면 도구 경로의 모호성을 방지하고 action_config의 의도(작업의 속성이 도구 체인의 한 곳에 명확하게 설명됨)를 적용할 수 있습니다.

도구 생성자 사용

action_config는 tools 매개변수를 통해 도구 집합을 지정할 수 있습니다. tool() 생성자는 다음 매개변수를 사용합니다.

지정된 action_config의 경우 단일 tool만 도구 경로와 실행 요구사항을 Bazel 작업에 적용합니다. 기능 구성과 일치하는 with_feature이 설정된 도구가 발견될 때까지 action_config에서 tools 속성을 반복하여 도구를 선택합니다(자세한 내용은 이 페이지의 앞부분에 있는 기능 관계 참고). 빈 기능 구성에 해당하는 기본 도구로 도구 목록을 종료해야 합니다.

사용 예

기능과 작업을 함께 사용하여 다양한 교차 플랫폼 시맨틱으로 Bazel 작업을 구현할 수 있습니다. 예를 들어 macOS에서 디버그 심볼을 생성하려면 컴파일 작업에서 심볼을 생성한 다음 링크 작업 중에 특수 도구를 호출하여 압축된 dsym 보관 파일을 만든 다음 해당 보관 파일을 압축 해제하여 Xcode에서 사용할 수 있는 애플리케이션 번들과 .plist 파일을 생성해야 합니다.

Bazel을 사용하면 이 프로세스를 다음과 같이 구현할 수 있습니다. 여기서 unbundle-debuginfo는 Bazel 작업입니다.

load("@rules_cc//cc:defs.bzl", "ACTION_NAMES")

action_configs = [
    action_config (
        action_name = ACTION_NAMES.cpp_link_executable,
        tools = [
            tool(
                with_features = [
                    with_feature(features=["generate-debug-symbols"]),
                ],
                path = "toolchain/mac/ld-with-dsym-packaging",
            ),
            tool (path = "toolchain/mac/ld"),
        ],
    ),
]

features = [
    feature(
        name = "generate-debug-symbols",
        flag_sets = [
            flag_set (
                actions = [
                    ACTION_NAMES.c_compile,
                    ACTION_NAMES.cpp_compile
                ],
                flag_groups = [
                    flag_group(
                        flags = ["-g"],
                    ),
                ],
            )
        ],
        implies = ["unbundle-debuginfo"],
   ),
]

이 동일한 기능은 fission를 사용하는 Linux나 .pdb 파일을 생성하는 Windows에서 완전히 다르게 구현될 수 있습니다. 예를 들어 fission 기반 디버그 심볼 생성 구현은 다음과 같습니다.

load("@rules_cc//cc:defs.bzl", "ACTION_NAMES")

action_configs = [
    action_config (
        name = ACTION_NAMES.cpp_compile,
        tools = [
            tool(
                path = "toolchain/bin/gcc",
            ),
        ],
    ),
]

features = [
    feature (
        name = "generate-debug-symbols",
        requires = [with_feature_set(features = ["dbg"])],
        flag_sets = [
            flag_set(
                actions = [ACTION_NAMES.cpp_compile],
                flag_groups = [
                    flag_group(
                        flags = ["-gsplit-dwarf"],
                    ),
                ],
            ),
            flag_set(
                actions = [ACTION_NAMES.cpp_link_executable],
                flag_groups = [
                    flag_group(
                        flags = ["-Wl", "--gdb-index"],
                    ),
                ],
            ),
      ],
    ),
]

플래그 그룹

CcToolchainConfigInfo를 사용하면 특정 목적을 제공하는 그룹으로 플래그를 번들로 묶을 수 있습니다. 플래그 값 내에서 미리 정의된 변수를 사용하여 플래그를 지정할 수 있습니다. 컴파일러는 빌드 명령어에 플래그를 추가할 때 이를 확장합니다. 예를 들면 다음과 같습니다.

flag_group (
    flags = ["%{output_execpath}"],
)

이 경우 플래그의 콘텐츠는 작업의 출력 파일 경로로 대체됩니다.

플래그 그룹은 목록에 표시되는 순서대로(위에서 아래, 왼쪽에서 오른쪽) 빌드 명령으로 확장됩니다.

빌드 명령어에 추가될 때 값이 다른 상태로 반복되어야 하는 플래그의 경우 플래그 그룹은 list 유형의 변수를 반복할 수 있습니다. 예를 들어 list 유형의 변수 include_path은 다음과 같습니다.

flag_group (
    iterate_over = "include_paths",
    flags = ["-I%{include_paths}"],
)

include_paths 목록의 각 경로 요소에 대해 -I<path>로 확장됩니다. 플래그 그룹 선언의 본문에 있는 모든 플래그 (또는 flag_group)는 하나의 단위로 확장됩니다. 예를 들면 다음과 같습니다.

flag_group (
    iterate_over = "include_paths",
    flags = ["-I", "%{include_paths}"],
)

include_paths 목록의 각 경로 요소에 대해 -I <path>로 확장됩니다.

변수는 여러 번 반복될 수 있습니다. 예를 들면 다음과 같습니다.

flag_group (
    iterate_over = "include_paths",
    flags = ["-iprefix=%{include_paths}", "-isystem=%{include_paths}"],
)

다음으로 확장됩니다.

-iprefix=<inc0> -isystem=<inc0> -iprefix=<inc1> -isystem=<inc1>

변수는 점 표기법을 사용하여 액세스할 수 있는 구조에 해당할 수 있습니다. 예를 들면 다음과 같습니다.

flag_group (
    flags = ["-l%{libraries_to_link.name}"],
)

구조는 중첩될 수 있으며 시퀀스를 포함할 수도 있습니다. 이름 충돌을 방지하고 명시적으로 지정하려면 필드를 통해 전체 경로를 지정해야 합니다. 예를 들면 다음과 같습니다.

flag_group (
    iterate_over = "libraries_to_link",
    flag_groups = [
        flag_group (
            iterate_over = "libraries_to_link.shared_libraries",
            flags = ["-l%{libraries_to_link.shared_libraries.name}"],
        ),
    ],
)

조건부 확장

플래그 그룹은 expand_if_available, expand_if_not_available, expand_if_true, expand_if_false 또는 expand_if_equal 속성을 사용하여 특정 변수 또는 필드의 존재 여부에 따라 조건부 확장을 지원합니다. 예를 들면 다음과 같습니다.

flag_group (
    iterate_over = "libraries_to_link",
    flag_groups = [
        flag_group (
            iterate_over = "libraries_to_link.shared_libraries",
            flag_groups = [
                flag_group (
                    expand_if_available = "libraries_to_link.shared_libraries.is_whole_archive",
                    flags = ["--whole_archive"],
                ),
                flag_group (
                    flags = ["-l%{libraries_to_link.shared_libraries.name}"],
                ),
                flag_group (
                    expand_if_available = "libraries_to_link.shared_libraries.is_whole_archive",
                    flags = ["--no_whole_archive"],
                ),
            ],
        ),
    ],
)

CcToolchainConfigInfo 참조

이 섹션에서는 C++ 규칙을 성공적으로 구성하는 데 필요한 빌드 변수, 기능, 기타 정보를 참조로 제공합니다.

CcToolchainConfigInfo 빌드 변수

다음은 CcToolchainConfigInfo 빌드 변수의 참조입니다.

잘 알려진 기능

다음은 기능과 활성화 조건에 대한 참고 자료입니다.

기존 기능 패치 로직

Bazel은 이전 버전과의 호환성을 위해 도구 모음의 기능에 다음 변경사항을 적용합니다.

• legacy_compile_flags 기능을 도구 모음 상단으로 이동
• default_compile_flags 기능을 도구 모음 상단으로 이동
• dependency_file (없는 경우) 기능을 도구 모음 상단에 추가
• pic (없는 경우) 기능을 도구 모음 상단에 추가
• per_object_debug_info (없는 경우) 기능을 도구 모음 상단에 추가
• preprocessor_defines (없는 경우) 기능을 도구 모음 상단에 추가
• includes (없는 경우) 기능을 도구 모음 상단에 추가
• include_paths (없는 경우) 기능을 도구 모음 상단에 추가
• fdo_instrument (없는 경우) 기능을 도구 모음 상단에 추가
• fdo_optimize (없는 경우) 기능을 도구 모음 상단에 추가
• cs_fdo_instrument (없는 경우) 기능을 도구 모음 상단에 추가
• cs_fdo_optimize (없는 경우) 기능을 도구 모음 상단에 추가
• fdo_prefetch_hints (없는 경우) 기능을 도구 모음 상단에 추가
• autofdo (없는 경우) 기능을 도구 모음 상단에 추가
• build_interface_libraries (없는 경우) 기능을 도구 모음 상단에 추가
• dynamic_library_linker_tool (없는 경우) 기능을 도구 모음 상단에 추가
• shared_flag (없는 경우) 기능을 도구 모음 상단에 추가
• linkstamps (없는 경우) 기능을 도구 모음 상단에 추가
• output_execpath_flags (없는 경우) 기능을 도구 모음 상단에 추가
• runtime_library_search_directories (없는 경우) 기능을 도구 모음 상단에 추가
• library_search_directories (없는 경우) 기능을 도구 모음 상단에 추가
• archiver_flags (없는 경우) 기능을 도구 모음 상단에 추가
• libraries_to_link (없는 경우) 기능을 도구 모음 상단에 추가
• force_pic_flags (없는 경우) 기능을 도구 모음 상단에 추가
• user_link_flags (없는 경우) 기능을 도구 모음 상단에 추가
• legacy_link_flags (없는 경우) 기능을 도구 모음 상단에 추가
• static_libgcc (없는 경우) 기능을 도구 모음 상단에 추가
• fission_support (없는 경우) 기능을 도구 모음 상단에 추가
• strip_debug_symbols (없는 경우) 기능을 도구 모음 상단에 추가
• coverage (없는 경우) 기능을 도구 모음 상단에 추가
• llvm_coverage_map_format (없는 경우) 기능을 도구 모음 상단에 추가
• gcc_coverage_map_format (없는 경우) 기능을 도구 모음 상단에 추가
• fully_static_link (없는 경우) 기능을 도구 모음 하단에 추가
• user_compile_flags (없는 경우) 기능을 도구 모음 하단에 추가
• sysroot (없는 경우) 기능을 도구 모음 하단에 추가
• unfiltered_compile_flags (없는 경우) 기능을 도구 모음 하단에 추가
• linker_param_file (없는 경우) 기능을 도구 모음 하단에 추가
• compiler_input_flags (없는 경우) 기능을 도구 모음 하단에 추가
• compiler_output_flags (없는 경우) 기능을 도구 모음 하단에 추가

기능 목록이 길어집니다. Starlark의 Crosstool이 완료되면 이를 없앨 계획입니다. 궁금한 독자는 CppActionConfigs의 구현을 참고하고, 프로덕션 도구 모음의 경우 no_legacy_features를 추가하여 도구 모음을 더 독립적으로 만드는 것이 좋습니다.