【自定义IDEA自带的在Groovy中生成POJO的文件，实现生成Java实体类】

最新推荐文章于 2025-07-01 15:22:50 发布

原创最新推荐文章于 2025-07-01 15:22:50 发布 · 497 阅读

4 ·

CC 4.0 BY-SA版权

文章标签：

#java #intellij-idea #数据库

JAVA 同时被 2 个专栏收录

20 篇文章

订阅专栏

数据库

5 篇文章

订阅专栏

文章目录

前言
实现步骤

前言

在这里插入图片描述
在构建完maven项目后，会有临时文件喝控制台的目录，找到如图所示的Generate pOJOs.groovy文件。

实现步骤

修改groovy文件

将原本文件中的内容，修改为：

import com.intellij.database.model.DasTable
import com.intellij.database.model.ObjectKind
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil
import java.io.*
import java.text.SimpleDateFormat

/*
 * Available context bindings:
 *   SELECTION   Iterable<DasObject>
 *   PROJECT     project
 *   FILES       files helper
 */
packageName = ""
/**
 * 将数据库字段类型转换为Java类型 键是正则表达式，值是对应的Java类型
 */
typeMapping = [
        (~/(?i)bigint/)                          : "Long",
        (~/(?i)int|tinyint|smallint|mediumint/)  : "Integer",
        (~/(?i)bool|bit/)                        : "Boolean",
        (~/(?i)float|double|decimal|real/)       : "Double",
        (~/(?i)datetime|timestamp|date|time/)    : "Date",
        (~/(?i)blob|binary|bfile|clob|raw|image/): "InputStream",
        (~/(?i)/)                                : "String"
]


/**
 * 使用 FILES.chooseDirectoryAndSave 方法弹出一个目录选择对话框，让用户选择一个目录来存储生成的文件
 */
FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
    SELECTION.filter { it instanceof DasTable && it.getKind() == ObjectKind.TABLE }.each { generate(it, dir) }
}

/**
 * 生成文件-定义文件名称和编码
 * @param table
 * @param dir
 * @return
 */
def generate(table, dir) {
    def className = javaName(table.getName(), true)// 表名转换成Java类名
    def fields = calcFields(table)// 获取字段
    packageName = getPackageName(dir)// 获取包名
    // 使用这个设置我们输出的字符编码
    PrintWriter printWriter = new PrintWriter(new OutputStreamWriter(new FileOutputStream(new File(dir, className + ".java")), "UTF-8"))
    printWriter.withPrintWriter {out -> generate(out, className, fields,table)}
}

// 获取包所在文件夹路径
def getPackageName(dir) {
    return dir.toString().replaceAll("\\\\", ".").replaceAll("/", ".").replaceAll("^.*src(\\.main\\.java\\.)?", "") + ";"
}

/**
 * 填充文件内容，即生成POJO类的代码
 * 包声明与导入、类声明、属性(生成每个字段的定义)声明、getter/setter方法
 * @param out
 * @param className
 * @param fields
 * @param table
 * @return
 */
def generate(out, className, fields,table) {
    out.println "package $packageName"
    out.println ""
//    out.println "import java.io.Serializable;"
    out.println "import lombok.Data;"
    out.println "import lombok.experimental.Accessors;"
//    out.println "import io.swagger.annotations.ApiModelProperty;"
    Set types = new HashSet()

    // 控制所需类型导包
    fields.each() {
        types.add(it.type)
    }

    if (types.contains("Date")) {
        // 按照自己的序列化包导入，我采用的是jackson
        out.println "import com.fasterxml.jackson.annotation.JsonFormat;"
        out.println "import java.util.Date;"
    }

    if (types.contains("InputStream")) {
        out.println "import java.io.InputStream;"
    }
    out.println ""
    out.println "/**\n" +
            " * @description $className \n" +
            " * @author  jiang\n" +
            " * @Date " + new SimpleDateFormat("yyyy-MM-dd").format(new Date()) + "\n"+
            " */"
    out.println ""
    out.println "@Data"
    out.println "@Accessors(chain = true)"
//    out.println "@Table ( name =\""+table.getName() +"\" )" 这里是指定实体类对应的表名
    out.println "public class $className {"// implements Serializable
    out.println ""
//    out.println genSerialID()
    fields.each() {
        out.println ""
        // 输出注释
        if (isNotEmpty(it.commoent)) {
            out.println "\t/**"
            out.println "\t * ${it.commoent.toString()}"
            out.println "\t */"
//            out.println "\t@ApiModelProperty(value = \"${it.commoent}\")"
        }
        // 如果是日期类型，我们进行格式化
        if (typeIsDate(it.type)){
            out.println "\t@JsonFormat(pattern = \"yyyy-MM-dd\",timezone = \"GMT+8\")"
        }

        // 输出成员变量
        out.println "\tprivate ${it.type} ${it.name};"
    }

    out.println ""
    out.println "}"
}

/**
 * 计算字段
 * 从给定的表对象 table 中提取列信息，并将其转换为一个包含列名、Java名称、类型、注释等信息的列表
 * @param table
 * @return
 */
def calcFields(table) {
    DasUtil.getColumns(table).reduce([]) { fields, col ->
        def spec = Case.LOWER.apply(col.getDataType().getSpecification())

        def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
        def comm =[
                colName : col.getName(),
                name :  javaName(col.getName(), false),
                type : typeStr,
                commoent: col.getComment(),
                annos: ""]
        fields += [comm]
    }
}

/**
 * 将给定的字符串转换为Java类名
 * @param str
 * @param capitalize
 * @return
 */
def javaName(str, capitalize) {
    def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
            .collect { Case.LOWER.apply(it).capitalize() }
            .join("")
            .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
    capitalize || s.length() == 1? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

/**
 * 判断字符串是否为空
 * @param content
 * @return
 */
def isNotEmpty(content) {
    return content != null && content.toString().trim().length() > 0
}

/**
 * 判断类型是否为日期
 * @param type
 * @return
 */
def typeIsDate(type){
    return type != null && type.toString().trim().equalsIgnoreCase("date")
}

/**
 * 将字符串转换为驼峰或下划线风格
 * @param str
 * @param toCamel
 * @return
 */
static String changeStyle(String str, boolean toCamel){
    if(!str || str.size() <= 1)
        return str

    if(toCamel){
        String r = str.toLowerCase().split('_').collect{cc -> Case.LOWER.apply(cc).capitalize()}.join('')
        return r[0].toLowerCase() + r[1..-1]
    }else{
        str = str[0].toLowerCase() + str[1..-1]
        return str.collect{cc -> ((char)cc).isUpperCase() ? '_' + cc.toLowerCase() : cc}.join('')
    }
}