屏幕数据展示与转换-CSDN博客

在屏幕中显示数据，且要为十进制数据

一、首先要编写三个子程序来解决三个主要问题：

解决在屏幕中如何显示内容的问题
解决如何将内存中的二进制数转换成十进制的ASCII码值的问题
解决除法的溢出问题解决除法的溢出问题
代码如下：

assume cs:code 

;es:bx	
data segment  
	;  bx= 0
	db '1975','1976','1977','1978','1979','1980','1981','1982','1983'
	db '1984','1985','1986','1987','1988','1989','1990','1991','1992'
	db '1993','1994','1995'
	;以上是表示21年的21个字符串
	
	;bx+84
	dd 16,22,382,1356,2390,8000,16000,24486,50065,97479,140417,197514
	dd 245980,590827,803530,1183000,1843000,2759000,3753000,4649000,5937000
	;以上是表示21年公司总收入的21个dword型数据
	
	
	; bp = 168
	dw 3,7,9,13,28,38,130,220,476,778,1001,1442,2258,2793,4037,5635,8226
	dw 11542,14430,15257,17800
	;以上是表示21年公司雇员人数的21个word型数据

data ends 

;ds:si
table segment
		;21表示数据个数
		db 21 dup('year    x          y        z  ',0)
				  ;0	  ;8         ;19     ;28
table ends

stack segment
		db 64 dup(0)
stack ends

code segment
;一旦这行和最后的一行分别报出error：A2105和error：A2009的错误时，有可能start后面是中式分号
start:
			mov ax,stack
			mov ss,ax
			mov sp,64

			mov ax,data
			mov es,ax
			mov bx,0
			mov bp,168  ;4x21+4x21=168

			mov ax,table
			mov ds,ax
			mov si,0

			mov cx,21

			pidea_21:

					;复制年份
					mov ax,es:[bx]
					mov [si],ax
					mov ax,es:[bx+2]
					mov [si+2],ax


					;将总收入转换成字符串
					;接收dd的低位
					mov ax,es:[bx+84]
					;接收dd的高位
					mov dx,es:[bx+84+2]

					push si
					add si,8
					call dtoc
					pop si


					;将员工人数转换成字符串
					mov ax,es:[bp]
					mov dx,0
					
					push si
					add si,19
					call dtoc
					pop si


					;计算平均收入，将其转换成字符串
					mov ax,es:[bx+84]
					mov dx,es:[bx+84+2]
					div word ptr es:[bp]

					; ax 存放的就是平均收入
					mov dx,0
					push si
					add si,28
					call dtoc
					pop si


					;将table中的数据显示
					;行号：si/32

					mov ax,si
					push bx
					push cx
					mov bl,32
					div bl
					mov dh,al   ;行号进dh
					mov dl,0
					mov cl,71h
					call show
					pop cx		
					pop bx
										
					add bx,4
					add bp,2
					add si,32


			loop pidea_21

			mov ax,4c00h
			int 21h


	

	;三个子程序：1.将数据显示到屏幕中  2.解决除法运算时，可能出现的数据溢出问题  3.将十进制数据转换成字符串

	;名称：show
	;功能：将data数据显示到屏幕中,显示一个用0结尾的字符串，0的作用是判断cl
	;参数：行号：dh,列号:dl,颜色:cl  字符串首地址：es:[bx]
	;返回：无具体返回值

	show:
			push ax
			push bx
			push cx
			push dx
			push es
			push si 


		show_start:	

			mov ax,0b800h
			mov es,ax

			; 计算行偏移 行号x160  两个八位内存单元，一个默认放在al中，所得结果放在ax中
			mov al,160
			mul dh

			; 计算列偏移 列号x2  两数相加，先将dh清空，以免影响计算结果
			mov dh,0
			add dx,dx

			;计算总偏移量
			mov bx,ax
			add bx,dx


			;将颜色代码cl的值转移到dl中,因为下面要用到cl作为循环结束判定条件
			mov dl,cl

			String_copy:
					mov ch,0
					mov cl,[si]
					;检查所显示的数是否为0
					jcxz String_OK 
					mov es:[bx],cl
					mov es:[bx+1],dl
					inc si
					add bx,2

					jmp short String_copy

		String_OK:
					pop si
					pop es
					pop dx
					pop cx
					pop bx
					pop ax
	ret



	;名称：divdm
	;功能：解决除法运算时，可能出现的数据溢出问题
	;参数：被除数：ax+dx 32位组合   除数：cx
 	;返回：商：ax+dx    余数：cx

 	divdm:
 			push bx
 			push ax

 			mov ax,dx
 			mov dx,0

 			;第一次除
 			div cx
 			;最终除后商的高16位先放入bx中
 			mov bx,ax

 			pop ax
 			;第二次除
 			div cx
 			;将最后所除结果放入cx中
 			mov cx,dx
 			;将第一次除法所得商从bx放入dx中
 			mov dx,bx 

 			pop bx
 	ret


 	;名称：dtoc
 	;功能：将十进制数据转化为字符串
 	;参数：ds:[si]指向最终字符串首地址  ax和dx分别存放待转化数据类型的低位和高位
 	;返回：无具体返回值

 	dtoc:
 			push ax
 			push bx
 			push cx
 			push dx
 			push di
 			push si

 			dtoc_str:
		 			;用di存放压入的数据个数
		 			mov di,0
 			dtoc_start:
 						mov cx,10
			 			;除10求余
			 			call divdm
			 			add cx,30h
			 			push cx
			 			inc di

			 			;判断循环结束条件：除到最后商和余数均为0
			 			mov cx,dx
			 			jcxz next
			 			jmp short dtoc_start

		 			next:
		 			mov cx,ax
		 			jcxz dtoc_end
		 			jmp short dtoc_start


		 	dtoc_end:
		 			mov cx,di  ;确定弹出的数据个数

		 			;堆栈中的数据出栈，送到目标内存位置
		 			dtoc_move:
		 						pop ax
		 						mov ds:[si],al
		 						inc si

		 			loop dtoc_move

		 	pop si
		 	pop di
		 	pop dx
		 	pop cx
		 	pop bx
		 	pop ax


 	ret


code ends
end start