ABAP: AT ... ENDAT的使用

参考博客：https://blog.csdn.net/sunnyonly1992/article/details/51682978

在ABAP报表程序中，经常会涉及到内表字段的统计。而统计一般会以一个或多个Key字段为节点，统计其他某些数值类型字段。这里我们就会用到AT… ENDAT。
这里包括： new , first , last , end of .
使用前提：一般在loop中使用，要提前对内表进行排序sort，排序的主键为统计时用到的节点（比如，按销售组织统计，节点为vkorg），Loop不能加where条件，在at 和 endat之间不能再使用loop语法。
那下面我们简单介绍一下四种用法：

1.AT NEW F.
    代码段..
ENDAT.

f是内表的一个字段，当内表中f字段以及f左边的任何字段内容发生变化时，执行其中的代码段。

2. AT END OF F.
        代码段..
    ENDAT.

当f字段以及f左边字段内容即将发生变化时，执行代码段。
上面这两种用法，看似很相近，但是 at new 是新变化的时候执行，也就是有变化的新一行loop进工作区时执行。而 at end of 则是下一行即将变化时执行，也就是有变化新一行的前一行loop时执行。
所以这里容易混淆，我们做个简单的例子更好理解区分。

REPORT z_zhangm_052.

TYPES:BEGIN OF ty_test,
name(3) TYPE c,
product TYPE c,
sales TYPE i,
END OF ty_test.

DATA:flag TYPE c,
     mark TYPE c.
DATA:i_test TYPE TABLE OF ty_test,
     w_test TYPE ty_test.
DATA:i_test2 TYPE TABLE OF ty_test,
     i_test3 TYPE TABLE OF ty_test.

w_test-name = '001'.
w_test-product = 'A'.
w_test-sales = 10.
APPEND w_test TO i_test.

w_test-name = '001'.
w_test-product = 'B'.
w_test-sales = 20.
APPEND w_test TO i_test.

w_test-name = '002'.
w_test-product = 'A'.
w_test-sales = 20.
APPEND w_test TO i_test.

w_test-name = '002'.
w_test-product = 'B'.
w_test-sales = 30.
APPEND w_test TO i_test.


w_test-name = '002'.
w_test-product = 'C'.
w_test-sales = 60.
APPEND w_test TO i_test.

w_test-name = '003'.
w_test-product = 'A'.
w_test-sales = 30.
APPEND w_test TO i_test.

CLEAR:w_test.
SORT i_test BY name product .

LOOP AT i_test INTO w_test.
  AT NEW name.
    flag = 'X'.
  ENDAT.
  IF flag = 'X'.
    APPEND w_test TO i_test2.
    CLEAR:flag .
  ENDIF.

  AT END OF name.
    mark = 'X'.
  ENDAT.

  IF mark = 'X'.
    APPEND w_test TO i_test3.
    CLEAR:mark.
  ENDIF.

  CLEAR:w_test.

  AT FIRST.
    WRITE:/,'loop的第一行时，进入调用',sy-uzeit.
    wait up to 3 seconds.  "停留3秒
  ENDAT.

  AT LAST.
    WRITE:/,'loop最后一行时，进入调用',sy-uzeit.
  ENDAT.

ENDLOOP.



WRITE:/ '结果如下：'.
WRITE:/ 'AT NEW 用法：'.
LOOP AT i_test2 INTO w_test.
  WRITE:/ w_test-name,'  ',  w_test-product, w_test-sales.
  CLEAR:w_test.
ENDLOOP.
WRITE:/ .

WRITE:/ 'AT END OF 用法：'.
LOOP AT i_test3 INTO w_test.
  WRITE:/ w_test-name,'  ',  w_test-product, w_test-sales.
  CLEAR:w_test.
ENDLOOP.

执行结果显示如下截图：

这里写图片描述

通过上面的代码和最终结果，我们应该更加清晰这两种用法的区别，在统计之前，我们的内表I_TEST中有6条数据：
这里写图片描述
然后我们按照name，product排序。最然name是唯一关键字段，但name排在第一位，所以这里product加入排序并不影响，也是为了后面结果能更直观的显示出来。
排序后，我们loop内表，第一行，001 A 10 。
这时，进入at new 的代码段，因为这里name = 001，是新的一个name，如上代码。我们给flag赋值X，这样执行一条插入语句，将此行插入到结构完全一样的内表I_TEST2中，然后clear 标记字（不要忘记clear）。
loop第二行，001 B 20 。
这次，不会进入at new中的代码段了，因为name还是001没变。但是这次会进入at end of中的代码段，因为下一行的name是002，也就是前面说到的下一行即将变化时。这样，我们将此行append到I_TEST3中。
后面我就不多说了，总之以key字段为唯一标准。这样我们在统计内表中数据时，就可以根据不同key字段进行统计。

再提一点，我们上面的代码中为何用到两个标记位(其实一个就够了，为了看起来条理清晰)：flag，mark。

因为当进入at …endat中的时候，工作区中的值除了key字段，其他字段会全部变为默认值，字符型字段值全变为*，数值全部变为0：
这里写图片描述
而当跳出AT … END AT.语法块后，工作区内容恢复原样：
这里写图片描述
如图，由于这种特性，我们不将插入语句或赋值语句写在at endat之中，而是通过标记变量的方式解决，因为影响的只是工作区中的内容。
上面讲述了两种常用的，还有两种比较简单，我们不做例子代码，简单描述下：

   3.  AT FIRST.
       代码段..
  ENDAT.

4. AT LAST.
  代码段..
ENDAT.

上面这两种用法，就比较简单易懂了。一个是在loop的第一行时，进入调用；另一个是最后一行时。而且不用对Loop进行排序，也没有key字段。

在sap报表开发过程中，可能会经常用到at end of 和 at new.希望通过这篇博文能让大家对这两种用法更好的理解。
对于内表的统计，有时我们还会用到collect。后面我们会简单介绍下。
如果看我前面博文《将Excel导入SAP中》的朋友可能会注意到，代码中就使用了at end of 。废话不多说，大家自行掌握，欢迎探讨交流。