Word 文档分页拆分技巧
在 Word 中，将一个文档分页拆分成多个文档是非常有用的技巧，特别是在需要对文档进行分页处理或将文档发送给他人时。本文将介绍如何使用 VBA 编辑器来实现将一个 Word 文档按页分割成多个 Word 文档。
Step 1: 打开需要分割的文档
打开需要分割的 Word 文档，假设它的文件名叫做“原始文档.doc”。
Step 2: 打开 VBA 编辑器
键入 ALT+F11 打开 VBA 编辑器，然后选择菜单“插入-模块”，以便在 VBA 编辑器中编写代码。
Step 3: 编写 VBA 代码
在 VBA 编辑器中，贴上以下代码：
```vb
Option Explicit
Sub SplitPagesAsDocuments()
Dim oSrcDoc As Document, oNewDoc As Document
Dim strSrcName As String, strNewName As String
Dim oRange As Range
Dim nIndex As Integer
Dim fso As Object
Set fso = CreateObject("Scripting.FileSystemObject")
Set oSrcDoc = ActiveDocument
Set oRange = oSrcDoc.Content
oRange.Collapse wdCollapseStart
oRange.Select
For nIndex = 1 To ActiveDocument.Content.Information(wdNumberOfPagesInDocument)
oSrcDoc.Bookmarks("\page").Range.Copy
oSrcDoc.Windows(1).Activate
Application.Browser.Target = wdBrowsePage
Application.Browser.Next
strSrcName = oSrcDoc.FullName
strNewName = fso.BuildPath(fso.GetParentFolderName(strSrcName), _
fso.GetBaseName(strSrcName) & "_" & nIndex & "." & fso.GetExtensionName(strSrcName))
Set oNewDoc = Documents.Add
Selection.Paste
oNewDoc.SaveAs strNewName
oNewDoc.Close False
Next
Set oNewDoc = Nothing
Set oRange = Nothing
Set oSrcDoc = Nothing
Set fso = Nothing
MsgBox "结束！"
End Sub
```
Step 4: 运行 VBA 代码
键入 F5 运行 VBA 代码，直到看到“结束！”的提示信息。
Step 5: 检查生成的文档
检查当前文档所在路径下是否生成了若干名为“原始文档_n.doc”（n 代表其对应原始文档中的第几页）的文档，检查它们的内容是否就对应于原始文档每个页面的内容。
通过这五个步骤，我们就可以将一个 Word 文档分页拆分成多个 Word 文档，每个文档对应原始文档中的一页内容。这种技巧非常有用，特别是在需要对文档进行分页处理或将文档发送给他人时。
- 1
- 2
前往页