The Ring programming language version 1.5.2 book - Part 30 of 181

Ring Documentation, Release 1.5.2
object.z
Class Point x y z
We can mix between using braces and the dot operator to access the object in the same expression.
Example:
o1 = new Point
O1 { x=10 y=20 z=30 }.print()
Class Point x y z
func print see x + nl + y + nl + z
39.3 Composition
The object may contains other objects as attributes.
Using braces to access objects can be nested.
Example:
R1 = New Rectangle
{
Name = "Rectangle 1"
P1
{
X = 10
Y = 20
}
P2
{
X = 200
Y = 300
}
Color = "Blue"
}
see "Name : " + R1.Name + nl +
"Color: " + R1.Color + nl +
"P1 : (" + R1.P1.X + "," + R1.P1.Y + ")" + nl +
"P2 : (" + R1.P2.X + "," + R1.P2.Y + ")"
Class Rectangle
name color
p1 = new Point
p2 = new Point
Class Point x y
Output:
39.3. Composition 265

Name : Rectangle 1
Color: Blue
P1 : (10,20)
P2 : (200,300)
39.4 Setter and Getter
We can deﬁne methods to be used when we set and get object attributes.
Syntax:
Class ClassName
AttributeName
...
Func SetAttributeName
...
Func GetAttributeName
...
Example:
o1 = new person
o1.name = "Mahmoud" see o1.name + nl
o1 { name = "Ahmed" see name }
Class Person
name family = "Fayed"
func setname value
see "Message from SetName() Function!" + nl
name = value + " " + family
func getname
see "Message from GetName() Function!" + nl
return "Mr. " + name
Output:
Message from SetName() Function!
Message from GetName() Function!
Mr. Mahmoud Fayed
Message from SetName() Function!
Message from GetName() Function!
Mr. Ahmed Fayed
39.5 Private Attributes and Methods
We can deﬁne private attributes and methods after the keyword private inside the class body
39.4. Setter and Getter 266

Example:
o1 = new person {
name = "Test"
age = 20
print()
o1.printsalary()
}
try
see o1.salary
catch
see cCatchError + nl
done
try
o1.increasesalary(1000)
catch
see cCatchError + nl
done
Class Person
name age
func print
see "Name : " + name + nl +
"Age : " + age + nl
func printsalary
see "Salary : " + salary + nl
private
salary = 15000
func increasesalary x
salary += x
Output:
Name : Test
Age : 20
Salary : 15000
Error (R27) : Using private attribute from outside the class : salary
Error (R26) : Calling private method from outside the class : increasesalary
39.6 Operator Overloading
We can add the operator method to our class to enable using operators with the class objects.
Syntax:
Class ClassName
...
39.6. Operator Overloading 267

Func operator cOperator,Para
...
The function operator takes two paramters, the ﬁrst represent the operator and the second represent the second param-
eter after the operator.
Example:
o1 = new point { x = 10 y = 10 print("P1 : ") }
o2 = new point { x = 20 y = 40 print("P2 : ") }
o3 = o1 + o2
o3.print("P1+P2 : ")
class point x y
func operator cOperator,Para
result = new point
switch cOperator
on "+"
result.x = x + Para.x
result.y = y + Para.y
on "-"
result.x = x - Para.x
result.y = y - Para.y
off
return result
func print cPoint
see cPoint + "X : " + x + " Y : " + y + nl
Output:
P1 : X : 10 Y : 10
P2 : X : 20 Y : 40
P1+P2 : X : 30 Y : 50
39.7 Inheritance
We can create class from another class in the class deﬁnition using the keyword from.
Syntax:
Class <Class Name> [From <Parent Class Name>]
We can call a method in the parent class from the child class using the super object.
Syntax:
func methodname
...
super.methodname()
...
Example:
39.7. Inheritance 268

Func main
e1 = new Employee {
Name = "test"
age = 20
job = "programmer"
salary = 20000000
print()
}
Class Human
Name Age
func print
see "Name : " + name + nl + "Age : " + age + nl
Class Employee from Human
Job Salary
func print
super.print()
see "Job : " + job + nl + "Salary : " + salary + nl
Output:
Name : test
Age : 20
Job : programmer
Salary : 20000000
39.8 Dynamic Attributes
We can write instructions after the class name to be executed when we create new objects
Example:
o1 = new dynamicClass
see o1.var5 + nl # output 5
Class DynamicClass
for x = 1 to 10
cStr = "var" + x + " = " + x
eval(cStr)
next
Tip: in the previous example var1, var2, ..., var10 will be defined as attributes.
Tip: The problem with the previous example is that x and cStr will be defined as attributes too!
Note: we can write class definitions inside a string then using eval() we can execute the string to define the classes
39.9 Packages
We can create a package (a group of classes under a common name) using the next syntax
39.8. Dynamic Attributes 269

package PackageName
Class Class1
...
Class Class2
...
Class Class3
...
...
Example
o1 = new System.output.console
o1.print("Hello World")
Package System.Output
Class Console
Func Print cText
see cText + nl
Note: we can use the dot operator as part of the package name
Instead of typing the long name PackageName.ClassName we can use the import command
When we import a package, we can use any class inside this package directly.
Example
import system.output
o1 = new console {
print("Hello World")
}
Package System.Output
Class Console
Func Print cText
see cText + nl
39.10 Printing Objects
We can print the object state (attributes and values) using the see command.
Example:
see new point { x=10 y=20 z=30 }
class point x y z
Output:
x: 10.000000
y: 20.000000
z: 30.000000
39.11 Find() and List of Objects
We can use the ﬁnd() function to search inside a list of objects.
Syntax:
39.10. Printing Objects 270

Find(List,ItemValue,nColumn,cAttribute) ---> Item Index
Example:
myList1 = [new Company {position=3 name="Mahmoud" symbol="MHD"},
new Company {position=2 name="Bert" symbol="BRT"},
new Company {position=1 name="Ring" symbol="RNG"}
]
see find(mylist1,"Bert",1,"name") + nl
see find(mylist1,"Ring",1,"name") + nl
see find(mylist1,"Mahmoud",1,"name") + nl
see find(mylist1,"RNG",1,"symbol") + nl
see find(mylist1,"MHD",1,"symbol") + nl
see find(mylist1,"BRT",1,"symbol") + nl
see find(mylist1,3,1,"position") + nl
see find(mylist1,1,1,"position") + nl
see "Other" + nl
see find(mylist1,"test",1,"name") + nl
class company position name symbol
Output:
2
3
1
3
1
2
1
3
Other
0
0
0
39.12 Sort() and list of objects
We can sort a list of objects based on an object attribute using the Sort() function.
Syntax:
Sort(List,nColumn,cAttribute) ---> Sorted List based on Object Attribute
Example:
myList1 = [
new Company {position=3 name="Mahmoud" symbol="MHD"},
new Company {position=2 name="Bert" symbol="BRT"},
new Company {position=8 name="Charlie" symbol="CHR"},
new Company {position=6 name="Easy" symbol="FEAS"},
new Company {position=7 name="Fox" symbol="EFOX"},
new Company {position=5 name="Dog" symbol="GDOG"},
new Company {position=4 name="George" symbol="DGRG"},
39.12. Sort() and list of objects 271

new Company {position=1 name="Ring" symbol="RNG"}
]
see sort(mylist1,1,"name")
see copy("*",70) + nl
see sort(mylist1,1,"symbol")
see copy("*",70) + nl
see sort(mylist1,1,"position")
class company position name symbol
Output:
position: 2.000000
name: Bert
symbol: BRT
position: 8.000000
name: Charlie
symbol: CHR
position: 5.000000
name: Dog
symbol: GDOG
position: 6.000000
name: Easy
symbol: FEAS
position: 7.000000
name: Fox
symbol: EFOX
position: 4.000000
name: George
symbol: DGRG
position: 3.000000
name: Mahmoud
symbol: MHD
position: 1.000000
name: Ring
symbol: RNG
**********************************************************************
position: 2.000000
name: Bert
symbol: BRT
position: 8.000000
name: Charlie
symbol: CHR
position: 4.000000
name: George
symbol: DGRG
position: 7.000000
name: Fox
symbol: EFOX
position: 6.000000
name: Easy
symbol: FEAS
position: 5.000000
name: Dog
symbol: GDOG
position: 3.000000
name: Mahmoud
39.12. Sort() and list of objects 272

symbol: MHD
position: 1.000000
name: Ring
symbol: RNG
**********************************************************************
position: 1.000000
name: Ring
symbol: RNG
position: 2.000000
name: Bert
symbol: BRT
position: 3.000000
name: Mahmoud
symbol: MHD
position: 4.000000
name: George
symbol: DGRG
position: 5.000000
name: Dog
symbol: GDOG
position: 6.000000
name: Easy
symbol: FEAS
position: 7.000000
name: Fox
symbol: EFOX
position: 8.000000
name: Charlie
symbol: CHR
39.13 Using Self.Attribute and Self.Method()
Inside the class region (After the class name and before any method) and the class methods we can use self.attribute
and self.method()
Class Point
self.x = 10
self.y = 20
self.z = 30
func print
see self.x + nl + self.y + nl + self.z + nl
Note: using self.attribute in the class region to define the class attribute protect the class attributes from conflict with
global variables.
Tip: if you typed the class attributes with self.attribute and there are a global variable with the same name it will be
used and the attribute will not be defined.
Check the “Scope Rules” chapter to know about the conflict between the global variable name and the attribute name
Whay this may happens?
Because
• Because in the class region we can access global variables.
39.13. Using Self.Attribute and Self.Method() 273

• Before defining any variable, Ring try to find the variable and use it if it’s found.
Note: Try to avoid the global variables, use the main function and start their names with $
Tip: In large programs protect your classes and define their members using self.attribute
39.14 Using This.Attribute and This.Method()
Inside class methods we have access to the object scope directly. we don’t need to use Self.attribute or Self.method to
read/write attribute and call methods.
But we can use braces {} while we are inside methods to access another object, In this case the current object scope
will be changed while we are inside the brace.
How we can get access to our class attributes and methods while we are inside braces?
This can be done using This.Attribute and This.Method()
Example:
new point
class point
x=10 y=20 z=30
print()
func print
new UI {
display(this.x,this.y,this.z)
}
Class UI
func display x,y,z
see x + nl + y + nl + z + nl
39.14. Using This.Attribute and This.Method() 274

The Ring programming language version 1.5.2 book - Part 30 of 181

More Related Content

What's hot (20)

Similar to The Ring programming language version 1.5.2 book - Part 30 of 181 (17)

More from Mahmoud Samir Fayed (20)

Recently uploaded (20)

The Ring programming language version 1.5.2 book - Part 30 of 181