components/infobars/android/BUILD.gn

# Copyright 2020 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/android/rules.gni")

android_resources("java_resources") {
  sources = [
    "res/drawable-hdpi/infobar_shadow_left.9.png",
    "res/drawable-hdpi/infobar_shadow_top.png",
    "res/drawable-mdpi/infobar_shadow_left.9.png",
    "res/drawable-mdpi/infobar_shadow_top.png",
    "res/drawable-xhdpi/infobar_shadow_left.9.png",
    "res/drawable-xhdpi/infobar_shadow_top.png",
    "res/drawable-xxhdpi/infobar_shadow_left.9.png",
    "res/drawable-xxhdpi/infobar_shadow_top.png",
    "res/drawable-xxxhdpi/infobar_shadow_left.9.png",
    "res/drawable-xxxhdpi/infobar_shadow_top.png",
    "res/layout/infobar_control_icon_with_description.xml",
    "res/layout/infobar_control_message.xml",
    "res/layout/infobar_control_spinner.xml",
    "res/layout/infobar_control_spinner_drop_down.xml",
    "res/layout/infobar_control_spinner_view.xml",
    "res/layout/infobar_control_toggle.xml",
    "res/values/dimens.xml",
    "res/values/ids.xml",
  ]
  custom_package = "org.chromium.components.infobars"
  deps = [
    "//components/browser_ui/strings/android:browser_ui_strings_grd",
    "//components/browser_ui/widget/android:java_resources",
    "//components/strings",
    "//ui/android:ui_java_resources",
  ]
}

static_library("android") {
  sources = [
    "infobar_android.cc",
    "infobar_android.h",
  ]

  deps = [
    ":jni_headers",
    "//base",
    "//components/infobars/core",
  ]
}

android_library("java") {
  sources = [
    "java/src/org/chromium/components/infobars/InfoBar.java",
    "java/src/org/chromium/components/infobars/InfoBarCompactLayout.java",
    "java/src/org/chromium/components/infobars/InfoBarControlLayout.java",
    "java/src/org/chromium/components/infobars/InfoBarInteractionHandler.java",
    "java/src/org/chromium/components/infobars/InfoBarLayout.java",
    "java/src/org/chromium/components/infobars/InfoBarMessageView.java",
    "java/src/org/chromium/components/infobars/InfoBarUiItem.java",
  ]
  deps = [
    ":infobar_android_enums_java",
    ":java_resources",
    "//base:base_java",
    "//base:jni_java",
    "//components/browser_ui/widget/android:java",
    "//components/infobars/core:infobar_enums_java",
    "//third_party/android_deps:androidx_appcompat_appcompat_java",
    "//third_party/android_deps:androidx_appcompat_appcompat_resources_java",
    "//ui/android:ui_java",
  ]
  annotation_processor_deps = [ "//base/android/jni_generator:jni_processor" ]
}

java_cpp_enum("infobar_android_enums") {
  sources = [ "infobar_android.h" ]
}

android_library("infobar_android_enums_java") {
  deps = [ "//third_party/android_deps:androidx_annotation_annotation_java" ]

  srcjar_deps = [ ":infobar_android_enums" ]
}

generate_jni("jni_headers") {
  sources = [ "java/src/org/chromium/components/infobars/InfoBar.java" ]
}

android_library("javatests") {
  testonly = true
  sources = [
    "java/src/org/chromium/components/infobars/InfoBarControlLayoutTest.java",
  ]
  deps = [
    ":java",
    "//base:base_java",
    "//base:base_java_test_support",
    "//components/browser_ui/styles/android:java_resources",
    "//components/browser_ui/widget/android:java",
    "//third_party/android_deps:androidx_annotation_annotation_java",
    "//third_party/android_deps:androidx_appcompat_appcompat_java",
    "//third_party/android_support_test_runner:rules_java",
    "//third_party/android_support_test_runner:runner_java",
    "//third_party/junit:junit",
  ]
}