front_end/panels/css_overview/BUILD.gn

# Copyright 2020 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("../../../scripts/build/ninja/devtools_entrypoint.gni")
import("../../../scripts/build/ninja/devtools_module.gni")
import("../../../scripts/build/ninja/generate_css.gni")

generate_css("css_files") {
  sources = [
    "cssOverview.css",
    "cssOverviewCompletedView.css",
    "cssOverviewProcessingView.css",
    "cssOverviewSidebarPanel.css",
    "cssOverviewStartView.css",
  ]
}

import("../visibility.gni")

devtools_module("css_overview") {
  sources = [
    "CSSOverviewCompletedView.ts",
    "CSSOverviewController.ts",
    "CSSOverviewModel.ts",
    "CSSOverviewPanel.ts",
    "CSSOverviewProcessingView.ts",
    "CSSOverviewSidebarPanel.ts",
    "CSSOverviewStartView.ts",
    "CSSOverviewUnusedDeclarations.ts",
  ]

  deps = [
    "../../core/common:bundle",
    "../../core/host:bundle",
    "../../core/i18n:bundle",
    "../../core/platform:bundle",
    "../../core/root:bundle",
    "../../core/sdk:bundle",
    "../../generated:protocol",
    "../../models/text_utils:bundle",
    "../../ui/legacy:bundle",
    "../../ui/legacy/components/color_picker:bundle",
    "../../ui/legacy/components/data_grid:bundle",
    "../../ui/legacy/components/utils:bundle",
  ]
}

devtools_entrypoint("bundle") {
  entrypoint = "css_overview.ts"

  deps = [
    ":css_files",
    ":css_overview",
  ]

  visibility = [
    ":*",
    "../../../test/unittests/front_end/entrypoints/missing_entrypoints/*",
    "../../entrypoints/*",

    # TODO(crbug.com/1202788): Remove invalid dependents
    "../../ui/legacy/components/inline_editor/*",
  ]

  visibility += devtools_panels_visibility
}

devtools_entrypoint("meta") {
  entrypoint = "css_overview-meta.ts"

  deps = [ ":bundle" ]

  visibility = [ "../../entrypoints/*" ]
}